正运动技术

协助伙伴成功,是我们的价值所在

Assisting our partners to succeed is our value

首页 / 支持与服务 / 技术分享

Technical support

技术分享

快速入门 | 篇十五:运动控制器运动缓冲简介​

  之前正运动技术与大家分享了,运动控制器的固件升级、ZBasic程序开发、ZPLC程序开发、与触摸屏通讯和输入/输出IO的应用、运动控制器数据与存储的应用、运动控制器ZCAN、EtherCAT总线的使用、示波器的应用、多任务运行的特点、运动控制器中断的应用、U盘接口的使用、ZDevelop 编程软件的使用以及运动控制器的基础轴参数与基础运动控制指令等。

  今天,我们来讲解一下正运动技术运动控制器运动缓冲。

  视频教程:《视频教程:运动控制器运动缓冲简介》

  以下是图文详解

  01 材料准备与接线参考

  

  1.jpg

  

  

  02运动缓冲

  

  1.运动缓冲原理

  在运行运动指令时,为了防止程序堵塞,控制器提供了一个缓冲区来保存进入运动缓冲的运动缓冲队列,把这个功能叫做运动缓冲,这样程序就能正常向下扫描,不会堵塞。

  ZMotion运动控制器具有多级的运动缓冲,当运动缓冲开启的时候,程序在扫描识别到程序任务的第一条运动指令时,将运动指令分配到指定轴的运动缓冲区,电机开始运动,此时程序继续向下扫描到第二条运动指令时,再往运动缓冲区中存,在不断扫描存入运动指令的同时,从运动缓冲区中依次取出运动指令执行。

  MTYPE,NTYPE分别是当前运行的运动指令和第一个缓冲运动指令。

  任意一段程序的运动指令都可以进入任意轴的运动缓冲区,由轴号指定。

  每个轴的运动缓冲区都是独立的,互不干扰。

  

  2.jpg

  

  缓冲多条运动指令时,为了判断当前运动执行到哪一条,提供MOVE_MARK运动标号和MOVE_CURMARK当前运动标号指令。MOVE_MARK运动标号每扫描一条运动指令+1;MOVE_CURMARK指令为当前运动的标号,提示当前运动到第几条运动指令,所有运动完成后为-1。

  当前运动完成后会自动执行运动缓冲区内的下一条运动。运动指令全部执行完后,运动缓冲区为空,或者使用CANCEL/RAPIDSTOP指令清空运动缓冲区。

  SP指令也属于运动指令,使用SP运动指令(如MOVESP、MOVECIRCSP等直接在运动指令后方加上SP)时,SP速度FORCE_SPEED、ENDMOVE_SPEED和STRATMOVE_SPEED会随SP运动指令写入运动缓存区。

  SP运动指令与运动指令的区别:

  MOVE(100)的速度是SPEED=100,MOVESP(100)的速度是FORCE_SPEED=200。

  

  3.jpg

  

  2.运动缓冲区堵塞

  

  每个轴的运动缓冲空间是有限的,当扫描太多运动指令放入运动缓冲区时,多级运动缓冲区全部被塞满,如果程序继续扫描到更多的运动指令,程序也会被堵塞,直到运动指令依次完成并退出,运动缓冲区有了空位,运动指令才会继续进入运动缓冲区。

  例:以V3.10版本仿真器为例,默认为4096个运动缓冲,下图例程中显示该控制器的运动缓冲区最多能存459条圆弧插补指令,下载程序后后打印i的值为458,表示当前FOR循环并未执行完,程序堵塞了。

  

  4.jpg

  

  下图中,当从运动缓冲区取出部分运动指令执行之后,缓冲区有了空间,FOR循环继续执行,并存入运动指令到运动缓冲区。指令执行退出运动缓冲区后,只要运动缓冲区的空间够,新的运动指令一条条往运动缓冲区中存。

  

  5.jpg

  

  每个轴的运动缓冲都是独立的,互不干扰,且缓冲区大小相同,通过指令REMAIN_BUFFER(MTYPE) AXIS(n)查看某个轴的剩余可用缓冲区的个数。

  ZMC4系列运动控制器每个轴可支持多达4096段运动缓冲(不同型号的控制器缓冲个数有区别,具体情况参见控制器硬件手册说明或使用?*max打印查看),可以手动设置LIMIT_BUFFERED运动缓冲限制。

  不同的运动指令占用的缓冲空间是不同的,越复杂的运动占用的运动缓冲空间越多。

  例如:

  ZMC432控制器,运动缓冲区大小为4096,缓冲区一次性可缓冲的MOVE直线插补指令和MOVECIRC圆弧插补指令个数是不同的。

  插补运动缓冲在主轴的运动缓冲区。

  

  6.jpg

  

  3.运动缓冲例程

  

  RAPIDSTOP(2)

  WAIT IDLE(0)

  WAIT IDLE(1)

  BASE(0,1)

  ATYPE=1,1

  UNITS=100,100

  SPEED=100,100

  ACCEL=1000,1000

  DECEL=1000,1000

  DPOS=0,0

  MERGE=OFF     '关闭连续插补

  TRIGGER

  LIMIT_BUFFERED=3     '轴0/1运动缓冲区可缓冲运动指令个数设为3

  MOVE(60,40     '进入MTYPE,Buffer0

  MOVE(70,50)     '进入NTYPE,Buffer1

  MOVE(50,40)     'Buffer2

  MOVE(60,50)     '缓冲区满,暂不进入

  ?"轴0当前缓冲指令个数=" MOVES_BUFFERED(0)     '结果2

  ?"轴0剩余缓冲区个数=" REMAIN_BUFFER(1) AXIS(0)     '结果0

  ?"轴1剩余缓冲区个数=" REMAIN_BUFFER(1) AXIS(1)     '结果3

  END

  将轴的运动缓冲区可缓冲运动指令个数限制为3,此时运动缓冲区最多能装3条直线插补指令。

  共有4个直线插补指令,MOVE(60,40)占用轴0的MTYPE,轴0还能缓冲2个运动指令,轴0剩余缓冲数为0,且还有1条直线指令因为主轴轴0的运动缓冲区已满,还未进入运动缓冲区。

  等到MOVE(60,40)运动完成,MOVE(60,50)才能进轴0的运动缓冲区。

  

  7.jpg

  

  插补运动缓冲在主轴轴0里,故轴1的运动缓冲区是没有指令的,剩余缓冲大小为3。每条MOVE指令占用一个缓冲空间。

  

  8.jpg

  

  4.普通输出与运动缓冲中输出的区别

  

  普通输出指令程序扫描到该行指令便执行输出。

  运动缓冲中输出指令在程序扫描之后,将其存入运动缓冲区,运动缓冲区按先进先出的顺序依此取出指令执行,直到取出该输出指令时才会执行输出。

  RAPIDSTOP(2)

  WAIT IDLE(0)

  BASE(0)         '选择轴0

  DPOS=0

  UNITS=100     '脉冲当量

  SPEED=100     '速度

  ACCEL=1000     '加速度

  DECEL=1000     '减速度

  TRIGGER     '触发示波器采样

  OP(0,3,$0)     '关闭输出口0-3

  DELAY(1000)     '延时

  MOVE(100)

  MOVE_OP(1,ON)     '运动缓冲中输出

  OP(0,ON)     '普通输出

  例子运行效果:延时1s之后,程序扫描到OP指令,输出口0立即执行输出。

  MOVE_OP把IO操作指令填入运动缓冲区,所以在运行完MOVE(100)之后,输出口1才输出。

  

  9.jpg

  

  03 运动缓冲相关指令

  

  10.jpg

  

  1.MOVE_OP -- 缓冲输出

  语法:MOVE_OP (输出编号,输出状态)

  此指令随其他运动指令一起进入运动缓冲区,从运动缓冲区中取出执行时才操作OP输出,可以控制某个输出口单独输出信号,也可以批量输出,不会打断插补运动的连续性。

  BASE(0)

  ATYPE=1

  UNITS=100

  DPOS=0

  SPEED=100

  ACCEL=1000

  DECEL=1000

  MERGE=ON    '开启连续插补

  TRIGGER     '自动触发示波器

  OP(0,3,0)     '关闭输出口0-3

  MOVE(100)

  MOVE_OP (0,ON)     '等待上条运动完成后,OUT0输出信号

  MOVE(100)

  MOVE_OP (0,OFF)     '等待上条运动完成后,OUT0关闭信号

  MOVE_OP(1,3,5)     '批量输出,OUT1,3输出信号,OUT2不输出,5对应二进制101

  例子运行效果:第11-15行的运动指令依此存入运动缓冲区,按先进先出的顺序执行,MOVE(100)运动完后,MOVE_OP操作OUT0输出,继续执行第二个MOVE(100),然后MOVE_OP操作OUT0关闭,紧接着控制OUT1-3批量输出。

  

  11.jpg

  

  2.MOVE_OP2 -- 缓冲输出2

  语法:MOVE_OP2(输出编号,输出状态,输出多少ms后翻转)

  BASE轴运动缓冲加入一个输出口操作,指定时间后输出状态翻转。

  此指令随其他运动指令一起进入运动缓冲区,从运动缓冲区中取出执行时才操作OP输出,保持输出一定时间后关闭输出。

  单个轴同一时间只支持一个脉冲输出,第二个MOVE_OP2指令会自动关闭前面指令的脉冲。不会打断插补运动的连续性。

  RAPIDSTOP(2)

  WAIT IDLE(0)

  BASE(0)

  ATYPE=1

  UNITS=100

  DPOS=0

  SPEED=200

  ACCEL=1000

  DECEL=1000

  MERGE=ON '开启连续插补

  OP(0,OFF) '关闭OUT0口

  TRIGGER '自动触发示波器

  MOVE(500)

  MOVE_OP2 (0,ON,1000) '等待上条运动完成,输出口0保持输出1s后关闭,输出时不会阻碍下一条运动执行

  MOVE(-300)

  

  12.jpg

  

  3.MOVE_DELAY -- 缓冲延时

  语法:MOVE_DELAY(延时ms数)

  BASE轴运动缓冲加入一个延时。

  这个指令缓冲执行时不做任何运动,只延时指定时间。

  延时使前面的运动指令结束时速度会自动降为0,会打断插补运动的连续性。‍

  RAPIDSTOP(2)

  WAIT IDLE(0)

  BASE(0)

  ATYPE=1

  UNITS=100

  SPEED=100

  ACCEL=1000

  DECEL=1000

  DPOS=0

  MERGE=ON '开启连续插补

  TRIGGER '自动触发示波器

  MOVE(100)

  MOVE_DELAY(500) '两个MOVE中间等待500ms

  MOVE(200)

  

  13.jpg

  

  4.MOVE_AOUT -- 缓冲输出模拟量

  语法:MOVE_AOUT(DA编号,输出值)

  BASE轴运动缓冲加入一个AOUT指令。

  这个指令缓冲执行时不做任何运动,只修改AOUT值,不会打断插补运动的连续性。

  // 例子

  RAPIDSTOP(2)

  WAIT IDLE(0)

  BASE(0)

  ATYPE=1

  UNITS=100

  SPEED=100

  ACCEL=1000

  DECEL=1000

  DPOS=0

  MERGE=ON '开启连续插补

  AOUT(0)=0 'DA0通道赋值0

  TRIGGER '自动触发示波器

  MOVE(200)

  MOVE_AOUT(0, 30.5) '第一个运动完成后,将DA0通道赋值30.5

  MOVE(200)

  

  14.jpg

  

  5.MOVE_PAUSE——运动暂停

  暂停轴运动,只有在单轴或多轴插补运动时有效,多轴联动时一起暂停。

  可以通过AXISSTATUS来查询是否有暂停,暂停中轴的IDLE状态为0。

  当轴已经暂停或不在运动中时,调用这个指令会有警告输出,但不影响程序运行。某些运动不支持暂停,如VMOVE、同步运动指令等。

  语法:MOVE_PAUSE(模式值)

  

  15.jpg

  

  模式值0例子:MOVE_PAUSE(3)的执行效果与MOVE_PAUSE(0)类似。

  RAPIDSTOP(2)

  WAIT IDLE(0)

  BASE(0)

  ATYPE=1

  UNITS=100

  SPEED=100

  ACCEL=1000

  DECEL=1000

  DPOS=0

  MERGE=ON '开启连续插补

  MOVE(100) '当前运动

  MOVE(200)

  MOVE_PAUSE(0) '暂停当前运动

  DELAY(1000)

  ?DPOS(0) '打印结果:0,此时当前运动只运行了极短时间,扫描到MOVE_PAUSE时直接暂停

  模式值1例子:模式2在运动标号MOVE_MARK自动编号时效果与模式1类似,因为每条运动的标号都是不同的,运动完一条运动指令后,运动标号发生改变,MOVE_MARK(2)生效,立即暂停。

  模式2在手动设置MOVE_MARK时才与模式1不同。

  RAPIDSTOP(2)

  WAIT IDLE(0)

  BASE(0)

  ATYPE=1

  UNITS=100

  SPEED=100

  ACCEL=1000

  DECEL=1000

  DPOS=0

  MERGE=ON     '开启连续插补

  TRIGGER     '自动触发示波器

  MOVE(100)     '当前运动

  MOVE(200)

  MOVE_PAUSE(1)     '当前运动运行完暂停

  DELAY(2000)

  ?DPOS(0)     '打印结果:100

  

  16.jpg

  

  MOVE_PAUSE(1)或MOVE_PAUSE(2)

  模式值2例子:手动设置MOVE_MARK,通过MOVE_PAUSE(2)指令可以在MARK不同的边界处暂停。

  BASE(0)

  ATYPE=1

  UNITS=100

  DPOS=0

  SPEED=100

  ACCEL=1000

  DECEL=1000

  MERGE=ON

  TRIGGER

  MOVE_MARK =1 '设置为标号1

  MOVE(100)

  MOVE_MARK =1 '设置为标号1

  MOVE(150)

  MOVE_MARK =2 '设置为标号2

  MOVE(200)

  MOVE_PAUSE (2) '标号不一样时暂停

  DELAY(5000)

  ?DPOS(0) '打印结果:250

  

  17.jpg

  

  MOVE_PAUSE(2)


  6.MOVE_RESUME -- 运动恢复

  当BASE轴暂停暂停时,从暂停处继续运动。

  可以通过AXISSTATUS来查询是否有暂停,AXISSTATUS显示800000h,表示轴进入了暂停状态。

  BASE(0)

  ATYPE=1

  UNITS=100

  DPOS=0

  SPEED=100

  ACCEL=1000

  DECEL=1000

  MERGE=ON

  TRIGGER

  MOVE(100)     '当前运动

  MOVE(200)     '缓冲运动

  MOVE_PAUSE(1)     '当前运动完成后暂停

  DELAY(2000)     '等待当前运动完成

  ?DPOS(0)     '打印结果:100

  MOVE_RESUME     '继续运行

  WAIT IDLE(0)

  ?DPOS(0)     '打印结果:300

  

  18.jpg

  

  7.MOVE_TABLE -- 缓冲输出TABLE

  BASE轴运动缓冲加入一个TABLE。

  指令缓冲执行时不做任何运动,只修改TABLE,不会打断插补运动的连续性。

  语法:MOVE_TABLE(TABLE编号, 要修改的值)

  BASE(0)

  ATYPE=1

  UNITS=100

  DPOS=0

  SPEED=100

  ACCEL=1000

  DECEL=1000

  MERGE=ON

  TABLE(0)=0     '初始值设为0

  TRIGGER         '自动触发示波器

  MOVE(100)

  MOVE_TABLE(0, 60)         '等待运动完成后,TABLE(0)赋值60

  MOVE(160)

  WAIT IDLE(0)

  ?TABLE(0)         '打印修改后TABLE(0)的值,打印结果,60

  

  19.jpg

  

  轴0运动100后,TABLE(0)赋值60


  8.MOVE_PARA -- 缓冲参数

  BASE轴运动缓冲修改参数。

  这个指令缓冲执行时不做任何运动,只修改参数,不会打断插补运动的连续性。

  语法:MOVE_PARA(参数名,参数编号,参数值)

  参数名必须是?*set里面的非只读参数。

  RAPIDSTOP(2)

  WAIT IDLE(0)

  BASE(0)

  ATYPE=1

  UNITS=100

  SPEED=100 '初始速度

  ACCEL=1000

  DECEL=1000

  DPOS=0

  MERGE=ON '开启连续插补

  TRIGGER '自动触发示波器

  MOVE(200) '速度100

  MOVE_PARA(SPEED,0,200) '修改轴0的SPEED参数值为200

  MOVE(200) '速度200

  WAIT IDLE(0) '等待轴0停止

  ?SPEED '打印结果:200

  

  20.jpg

  

  9.MOVE_PWM -- 缓冲PWM

  BASE轴运动缓冲操作PWM。

  指令缓冲执行时不做任何运动,只操作PWM。

  PWM只能通过设置占空比为0来关闭,不能通过设置PWM频率为0实现,PWM频率一定要在PWM开启之前调整。

  语法:MOVE_PWM(编号,占空比[,频率])

  编号为支持PWM功能的输出口编号,查看硬件手册确认。

  占空比指有效电平占整个周期的比例;范围0-1,设置0时关闭pwm;一个周期中先输出有效电平,再输出无效电平。

  频率缺省为1KHz,硬件最大为1MHz,软件最大为2KHz。

  RAPIDSTOP(2)

  WAIT IDLE(0)

  MOVE_PWM(0, 0, 1000)     '关闭PWM

  BASE(0)

  ATYPE=1

  UNITS=100

  SPEED=100 '初始速度

  ACCEL=1000

  DECEL=1000

  DPOS=0

  TICKS = 10000

  MOVE(10)

  MOVE_PWM(0, 0.111, 2000)     '轴0运行到10时,操作PWM0输出

  MOVE_DELAY(100)

  MOVE_PWM(0, 0.555, 3000) '延时100ms,修改PWM0输出

  MOVE(20)

  MOVE_PWM(0, 0, 1000)     '关闭PWM

  WHILE NOT IDLE(0) 'IDLE(0)=-1后退出while循环

      ? -TICKS,PWM_DUTY(0),PWM_FREQ(0)

      DELAY(30)

  WEND

  例子运行效果:初始化关闭PWM输出,MOVE(10)运动完后,操作PWM0输出,保持100ms之后,修改PWM0输出的占空比和频率,再运行MOVE(20)后关闭PWM输出。WHILE循环在轴0运行时,每隔30ms打印一次PWM输出的占空比和频率,在轴0停止后,退出WHILE循环,不在打印。

  

  21.jpg

  

  10.MOVE_SYNMOVE -- 缓冲触发其他轴

  BASE轴运动缓冲触发其他轴运动,当前轴等待,等待其他轴运动完成,当前轴才继续运动。

  语法:MOVE_SYNMOVE(axisnum,dis[,ifsp])

  axisnum:需要同步运动的轴号

  dis:相对运动距离

  ifsp:是否使用SP运动, 缺省值0不使用,设为其他值使用

  RAPIDSTOP(2)

  WAIT IDLE(0)

  WAIT IDLE(1)

  BASE(0,1)

  DPOS=0,0

  ATYPE=1,1

  UNITS=100,100

  SPEED=100,100

  ACCEL=1000,1000

  DECEL=1000,1000

  MERGE=ON,ON

  TRIGGER

  MOVE(100)

  MOVE_SYNMOVE(1,120,0)     '轴0运行到100时,轴1开始运动120

  MOVE(100)     '待轴同步完成,轴0再继续运动

  

  22.jpg

  

  使用SP运动后的效果如下,将最后一位参数设置非0值 ,此时触发轴1的运动速度为FORCE_SPEED=200。

  

  23.jpg

  

  11.MOVE_ASYNMOVE -- 缓冲触发其他轴2

  BASE轴运动缓冲触发其他轴运动,当前轴不等待,仍继续运动。

  语法:MOVE_ASYNMOVE(axisnum,dis[,ifsp])

  axisnum:需要同步运动的轴号

  dis:相对运动距离

  ifsp:是否使用SP运动, 缺省值0不使用,设为其他值使用

  RAPIDSTOP(2)

  WAIT IDLE(0)

  WAIT IDLE(1)

  BASE(0,1)

  DPOS=0,0

  ATYPE=1,1

  UNITS=100,100

  SPEED=100,100

  ACCEL=1000,1000

  DECEL=1000,1000

  MERGE=ON,ON

  TRIGGER

  MOVE(100)

  MOVE_ASYNMOVE(1,120,0) '轴0运行到100时,轴1开始运动120

  MOVE(100) '待轴同步完成,轴0再继续运动

  

  24.jpg

  

  12.MOVE_TASK -- 缓冲开启任务

  BASE轴运动缓冲加入启动TASK。

  这个指令缓冲执行时不做任何运动,只启动任务,不会打断插补运动的连续性。

  语法:MOVE_TASK(任务号, 函数名)

  从运动缓冲全区取出MOVE_TASK指令执行时,将task_move标记的程序作为任务1开启,在任务窗口可以看到任务1已启动。

  

  25.jpg

  

  RAPIDSTOP(2)

  WAIT IDLE(0)

  BASE(0)

  ATYPE=1

  UNITS=100

  DPOS=0

  SPEED=100

  ACCEL=1000

  DECEL=1000

  MERGE=ON

  TRIGGER

  MOVE(100)

  MOVE_TASK(1,task_move)     '第一个运动完成后,将task_move作为任务1启动

  MOVE(100)

  END

  '任务1

  task_move:

      PRINT "TASK_MOVE"

  END

  

  26.jpg

  

  13.MOVE_WAIT -- 缓冲等待

  BASE轴运动缓冲加入一个条件判断。

  指令缓冲执行时不做任何运动,只等待指定的条件满足,前面的运动指令结束时速度会自动降为0。

  语法:MOVE_WAIT(参数名, 参数编号, 比较条件, 比较值)

  参数可以为:DPOS,MPOS,IN,AIN,VPSPEED,MSPEED,MODBUS_REG,MODBUS_IEEE,MODBUS_BIT,VECTOR_BUFFERED,REMAIN

  比较条件:1 参数值≥比较值;-1 参数值≤比较值;0 不建议使用

  RAPIDSTOP(2)

  WAIT IDLE(0)

  BASE(0)

  ATYPE=1

  UNITS=100

  DPOS=0

  SPEED=100

  ACCEL=1000

  DECEL=1000

  TRIGGER

  MOVE(100)

  MOVE_WAIT(IN, 0, 1, 1) '等待IN(0)有信号,才执行下一条运动

  MOVE(100)

  

  27.jpg

  

  14.MOVE_CANCEL--缓冲停止

  把CANCEL指令写入运动缓冲。

  语法:MOVE_CANCEL(轴号,模式值)

      0:取消当前运动,继续取缓冲区指令指令

      1:取消缓冲区的运动,当前运动仍然要执行完

      2:取消当前运动和缓冲区的运动,轴立即停止

      3:立即中断脉冲的发送

  RAPIDSTOP(2)

  WAIT IDLE(0)

  WAIT IDLE(1)

  BASE(0,1)

  DPOS=0,0

  ATYPE=1,1

  UNITS=100,100

  SPEED=100,100

  ACCEL=1000,1000

  DECEL=1000,1000

  MERGE=ON,ON:

  TRIGGER

  MOVE(50) AXIS(0)     '轴0当前运动

  MOVE(80) AXIS(1)     '轴1当前运动

  MOVE_CANCEL(1,2) AXIS(0)     '轴0缓冲里面写入停止轴1的指令

  MOVE(60) AXIS(0)     '轴0缓冲运动

  MOVE(70) AXIS(1)     '轴1缓冲运动,被取消

  例子运行效果:轴0运动50后,MOVE_CANCEL(1,2) AXIS(0)指令生效,CANCEL(2)模式取消轴1的当前运动和缓冲运动,轴1立刻停止,轴0继续运动。

  

  28.jpg

  

  15.LOADED -- 缓冲空

  用于判断轴的运动缓冲区是否为空,只读参数,返回值0表示运动缓冲区还有指令,返回值为-1表示运动缓冲区空。

  BASE(0)

  ATYPE=1

  UNITS=100

  SPEED=100

  ACCEL=1000

  DECEL=1000

  DPOS=0

  MERGE=ON         '开启连续插补

  OP(0,OFF)

  TRIGGER

  MOVE(100)         '当前运动

  MOVE(50)             '缓冲运动,此时缓冲区只有这一条运动

                              '当本条运动执行时,缓冲区就已经清空

  WAIT LOADED     '运动缓冲空即可往下执行

  OP(0,ON)             '打开OP0

  

  29.jpg

  

  WAIT LOADED 等待缓冲区空

  

  30.jpg

  

  WAIT IDLE 等待轴停止


  16.MOVE_MARK -- 运动标号

  

  下一条要调用的运动指令的MARK标号,这个标号会和运动指令一起写入运动缓冲。

  每调用一条运动指令,MOVE_MARK会自动加一。

  如果要强制指定MOVE_MARK,需要每次运动前都设定一次。

  通过MOVE_PAUSE (2)指令可以在MARK不同的边界处暂停。

  BASE(0)

  ATYPE=1

  UNITS=100

  DPOS=0

  SPEED=100

  ACCEL=1000

  DECEL=1000

  MERGE=OFF     '关闭连续插补

  OP(0,OFF)

  TRIGGER

  MOVE_MARK=0     '初始值:0

  MOVE(100)             '运动指令1

  MOVE_DELAY(1000)     '运动指令2

  MOVE(50)     '运动指令3

  MOVE_OP(0,ON)     '运动指令4

  MOVE(80)     '运动指令5

  PRINT MOVE_MARK     '打印结果:5

  

  31.jpg

  

  17.MOVE_CURMARK -- 当前运动标号

  返回当前轴正在运动指令的MOVE_MARK标号,编号默认从0开始,到运动指令总数减1。

  在轴参数窗口可以监控当前程序扫描到的运动指令个数,查看MOVE_MARK;和轴当前运行到了第几个运动指令,查看MOVE_CURMARK。

  BASE(0)

  ATYPE=1

  UNITS=100

  DPOS=0

  SPEED=100

  ACCEL=1000

  DECEL=1000

  MERGE=ON

  OP(1,OFF)

  TRIGGER

  MOVE_MARK =1

  MOVE(50)

  MOVE_MARK =2

  MOVE(100)

  MOVE_MARK =3

  MOVE(150)

  WAIT UNTIL MOVE_CURMARK = 2 '等待MOVE(100)开始执行的时候,开输出口1

  OP(1,ON)

  

  32.jpg

  

  正运动技术运动控制器运动缓冲就讲到这里。更多学习视频及图文请关注我们的公众号“正运动小助手”。

  本文由正运动小助手原创,欢迎大家转载,共同学习,一起提高中国智能制造水平。文章版权归正运动技术所有,如有转载请注明文章来源。

  

  33.jpg

  

邮箱留言

Copyright © 2013 正运动技术有限公司 Design by Zmotion 版权所有   粤ICP备13037187号    Powered by www.zmotion.com.cn 运动控制器-运动控制卡

在线咨询